home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / ANTFIELD.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-27  |  2.4 KB  |  93 lines
  1. 10  'ANTFIELD - Antenna Field Strength - 07 JUN 95  rev. 17 OCT 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  IF PROG$=""THEN GO$=EX$ ELSE GO$=PROG$
  4. 40  COMMON EX$,PROG$
  5. 50  CLS:KEY OFF
  6. 60  COLOR 7,0,1
  7. 70  UL$=STRING$(80,205)
  8. 80  U$="#####.###"
  9. 90  '
  10. 100  '.....start
  11. 110  COLOR 15,2
  12. 120  PRINT " ANTENNA FIELD STRENGTH";TAB(64);"(author unknown) ";
  13. 130  PRINT STRING$(80,32);
  14. 140  LOCATE CSRLIN-1,2:PRINT "modified by ";CHR$(34);"LB";CHR$(34);" Cebik, ";
  15. 150  PRINT "W4RNL, and edited for HAMCALC by George Murphy, VE3ERP"
  16. 160  COLOR 1,0:PRINT STRING$(80,223);:COLOR 7,0
  17. 170  '
  18. 180  PRINT " Press number in < > to choose standard units of measure:"
  19. 190  PRINT UL$;
  20. 200  PRINT "  < 1 >  Metric"
  21. 210  PRINT "  < 2 >  U.S.A./Imperial
  22. 220  PRINT UL$;
  23. 230  PRINT "    or Press < 0 > to EXIT"
  24. 240  Z$=INKEY$
  25. 250  IF Z$="1"THEN UM=1:UM$="metres":GOTO 290
  26. 260  IF Z$="2"THEN UM=0.3048:UM$="feet":GOTO 290
  27. 270  IF Z$="0"THEN CLS:CHAIN GO$
  28. 280  GOTO 240
  29. 290  VIEW PRINT 4 TO 24:CLS:VIEW PRINT:LOCATE 4
  30. 300  '
  31. 310  '.....inputs
  32. 320  M=7
  33. 330  PRINT TAB(M);
  34. 340  PRINT"Antenna field strength relatively close to an antenna is measured in"
  35. 350  PRINT TAB(M);
  36. 360  PRINT"volts per metre and can be reasonably estimated from the height of"
  37. 370  PRINT TAB(M);
  38. 380  PRINT"the antenna, the antenna power into a known impedance, the operating"
  39. 390  PRINT TAB(M);
  40. 400  PRINT"frequency, and the distance from the antenna."
  41. 410  PRINT UL$;
  42. 420  GOTO 490
  43. 430  '
  44. 440  '.....format input line
  45. 450  LOCATE CSRLIN-1:PRINT SPC(7);
  46. 460  LOCATE CSRLIN,59:PRINT USING U$;Z;
  47. 470  RETURN
  48. 480  '
  49. 490  '.....data input
  50. 500  V$=UM$
  51. 510  PRINT " ENTER: Effective antenna height..........................(";V$;")";
  52. 520  INPUT Z:GOSUB 440:PRINT " ";V$:B=Z*UM
  53. 530  '
  54. 540  V$="watts"
  55. 550  PRINT " ENTER: Power at antenna..................................(";V$;")";
  56. 560  INPUT Z:GOSUB 440:PRINT " ";V$:P=Z
  57. 570  '
  58. 580  V$="ohms"
  59. 590  PRINT " ENTER: Antenna impedance (not including transmatch)......(";V$;")";
  60. 600  INPUT Z:GOSUB 440:PRINT " ";V$:O=Z:I=SQR(P/O)
  61. 610  '
  62. 620  V$="MHz"
  63. 630  PRINT " ENTER: Operating frequency...............................(";V$;")";
  64. 640  INPUT Z:GOSUB 440:PRINT " ";V$:F=Z:W=300/F
  65. 650  '
  66. 660  V$=UM$
  67. 670  PRINT " ENTER: Distance from antenna.............................(";V$;")";
  68. 680  INPUT D:R=D*UM
  69. 690  E=(188*B*I)/(W*R)
  70. 700  V$="volts/metre"
  71. 710  LOCATE CSRLIN-1
  72. 720  PRINT "        Field strength @";D;UM$;" from antenna................";
  73. 730  LOCATE CSRLIN,59
  74. 740  PRINT USING U$;E;:PRINT " ";V$
  75. 750  GOSUB 800
  76. 760  VIEW PRINT 4 TO 24:CLS:VIEW PRINT:LOCATE 4
  77. 770  CLS:GOTO 100     'return to start
  78. 780  END
  79. 790  '
  80. 800  'HARDCOPY
  81. 810  GOSUB 920:LOCATE 25,2:COLOR 14,6
  82. 820  PRINT " Press 1 to print screen, 2 to print screen & ";
  83. 830  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  84. 840  Z$=INKEY$:IF Z$="3"THEN GOSUB 920:RETURN
  85. 850  IF Z$="1"OR Z$="2"THEN GOSUB 920:GOTO 870
  86. 860  GOTO 840
  87. 870  FOR QX=1 TO 24:FOR QY=1 TO 80
  88. 880  LPRINT CHR$(SCREEN(QX,QY));
  89. 890  NEXT QY:NEXT QX
  90. 900  IF Z$="2"THEN LPRINT CHR$(12)
  91. 910  GOTO 810
  92. 920  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  93.